From b239f0f45ffd0993cffc2a676651a0770b705fb5 Mon Sep 17 00:00:00 2001
From: Kirawi <67773714+kirawi@users.noreply.github.com>
Date: Tue, 10 Aug 2021 01:09:57 -0400
Subject: [PATCH] add java highlighting (#448)

---
 languages.toml                      |   8 ++
 runtime/queries/java/highlights.scm | 129 ++++++++++++++++++++++++++++
 2 files changed, 137 insertions(+)
 create mode 100644 runtime/queries/java/highlights.scm

diff --git a/languages.toml b/languages.toml
index 8cd092e48..15d78a1af 100644
--- a/languages.toml
+++ b/languages.toml
@@ -197,6 +197,14 @@ comment-token = "#"
 language-server = { command = "julia", args = [ "--startup-file=no", "--history-file=no", "-e", "using LanguageServer;using Pkg;import StaticLint;import SymbolServer;env_path = dirname(Pkg.Types.Context().env.project_file);server = LanguageServer.LanguageServerInstance(stdin, stdout, env_path, \"\");server.runlinter = true;run(server);" ] }
 indent = { tab-width = 2, unit = "  " }
 
+[[language]]
+name = "java"
+scope = "source.java"
+injection-regex = "java"
+file-types = ["java"]
+roots = []
+indent = { tab-width = 4, unit = "    " }
+
 # [[language]]
 # name = "haskell"
 # scope = "source.haskell"
diff --git a/runtime/queries/java/highlights.scm b/runtime/queries/java/highlights.scm
new file mode 100644
index 000000000..3f8ae0d50
--- /dev/null
+++ b/runtime/queries/java/highlights.scm
@@ -0,0 +1,129 @@
+; Methods
+
+(method_declaration
+  name: (identifier) @function.method)
+(method_invocation
+  name: (identifier) @function.method)
+(super) @function.builtin
+
+; Annotations
+
+(annotation
+  name: (identifier) @attribute)
+(marker_annotation
+  name: (identifier) @attribute)
+
+"@" @operator
+
+; Types
+
+(interface_declaration
+  name: (identifier) @type)
+(class_declaration
+  name: (identifier) @type)
+(enum_declaration
+  name: (identifier) @type)
+
+((field_access
+  object: (identifier) @type)
+ (#match? @type "^[A-Z]"))
+((scoped_identifier
+  scope: (identifier) @type)
+ (#match? @type "^[A-Z]"))
+
+(constructor_declaration
+  name: (identifier) @type)
+
+(type_identifier) @type
+
+[
+  (boolean_type)
+  (integral_type)
+  (floating_point_type)
+  (floating_point_type)
+  (void_type)
+] @type.builtin
+
+; Variables
+
+((identifier) @constant
+ (#match? @constant "^_*[A-Z][A-Z\d_]+"))
+
+(identifier) @variable
+
+(this) @variable.builtin
+
+; Literals
+
+[
+  (hex_integer_literal)
+  (decimal_integer_literal)
+  (octal_integer_literal)
+  (decimal_floating_point_literal)
+  (hex_floating_point_literal)
+] @number
+
+[
+  (character_literal)
+  (string_literal)
+] @string
+
+[
+  (true)
+  (false)
+  (null_literal)
+] @constant.builtin
+
+(comment) @comment
+
+; Keywords
+
+[
+  "abstract"
+  "assert"
+  "break"
+  "case"
+  "catch"
+  "class"
+  "continue"
+  "default"
+  "do"
+  "else"
+  "enum"
+  "exports"
+  "extends"
+  "final"
+  "finally"
+  "for"
+  "if"
+  "implements"
+  "import"
+  "instanceof"
+  "interface"
+  "module"
+  "native"
+  "new"
+  "open"
+  "opens"
+  "package"
+  "private"
+  "protected"
+  "provides"
+  "public"
+  "requires"
+  "return"
+  "static"
+  "strictfp"
+  "switch"
+  "synchronized"
+  "throw"
+  "throws"
+  "to"
+  "transient"
+  "transitive"
+  "try"
+  "uses"
+  "volatile"
+  "while"
+  "with"
+] @keyword