From b3b164f0d5decd02a02d7c3b571749fac47d7005 Mon Sep 17 00:00:00 2001
From: Charles Hall <charles@computer.surgery>
Date: Fri, 2 Sep 2022 15:26:42 -0700
Subject: [PATCH] Highlight SQL in `sqlx::{query,query_as}!()` in Rust (#3647)

---
 runtime/queries/rust/injections.scm | 27 +++++++++++++++++++++++++++
 1 file changed, 27 insertions(+)

diff --git a/runtime/queries/rust/injections.scm b/runtime/queries/rust/injections.scm
index 77c70805..704d8494 100644
--- a/runtime/queries/rust/injections.scm
+++ b/runtime/queries/rust/injections.scm
@@ -24,3 +24,30 @@
     name: (identifier) @_new (#eq? @_new "new"))
   arguments: (arguments (raw_string_literal) @injection.content)
   (#set! injection.language "regex"))
+
+; Highlight SQL in `sqlx::query!()`
+(macro_invocation
+  macro: (scoped_identifier
+    path: (identifier) @_sqlx (#eq? @_sqlx "sqlx")
+    name: (identifier) @_query (#eq? @_query "query"))
+  (token_tree
+    ; Only the first argument is SQL
+    .
+    [(string_literal) (raw_string_literal)] @injection.content
+  )
+  (#set! injection.language "sql"))
+
+; Highlight SQL in `sqlx::query_as!()`
+(macro_invocation
+  macro: (scoped_identifier
+    path: (identifier) @_sqlx (#eq? @_sqlx "sqlx")
+    name: (identifier) @_query_as (#eq? @_query_as "query_as"))
+  (token_tree
+    ; Only the second argument is SQL
+    .
+    ; Allow anything as the first argument in case the user has lower case type
+    ; names for some reason
+    (_)
+    [(string_literal) (raw_string_literal)] @injection.content
+  )
+  (#set! injection.language "sql"))