javascript queries: fix parameters (#3280)

runtime/queries/javascript/highlights-params.scm

@@ -1,12 +0,0 @@
-(formal_parameters
-  [
-    (identifier) @variable.parameter
-    (array_pattern
-      (identifier) @variable.parameter)
-    (object_pattern
-      [
-        (pair_pattern value: (identifier) @variable.parameter)
-        (shorthand_property_identifier_pattern) @variable.parameter
-      ])
-  ]
-)

runtime/queries/javascript/highlights.scm

@@ -47,6 +47,43 @@
   left: (identifier) @function
   right: [(function) (arrow_function)])
   
+; Function and method parameters
+;-------------------------------
+
+; (p) => ...
+(formal_parameters 
+  (identifier) @variable.parameter)
+
+; (...p) => ...
+(formal_parameters
+  (rest_pattern
+    (identifier) @variable.parameter))
+
+; ({ p }) => ...
+(formal_parameters
+  (object_pattern
+    (shorthand_property_identifier_pattern) @variable.parameter))
+
+; ({ a: p }) => ...
+(formal_parameters
+  (object_pattern
+    (pair_pattern
+      value: (identifier) @variable.parameter)))
+
+; ([ p ]) => ...
+(formal_parameters
+  (array_pattern
+    (identifier) @variable.parameter))
+
+; (p = 1) => ...
+(formal_parameters
+  (assignment_pattern
+    left: (identifier) @variable.parameter))
+
+; p => ...
+(arrow_function
+  parameter: (identifier) @variable.parameter)
+
 ; Function and method calls
 ;--------------------------
 

runtime/queries/javascript/locals.scm

@@ -14,6 +14,12 @@
 
 (pattern/identifier) @local.definition
 
+(pattern/rest_pattern 
+  (identifier) @local.definition)
+  
+(arrow_function
+  parameter: (identifier) @local.definition)
+
 (variable_declarator
   name: (identifier) @local.definition)